chess - online multiplayer chess game (note server currently down)


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93

extends Control
class_name Lobby

onready var address: LineEdit = find_node("Address")
onready var buttons := find_node("buttons")
onready var status_ok := find_node("StatusOK")
onready var status_fail := find_node("StatusFail")


func toggle(onoff: bool) -> void:
	get_parent().visible = onoff


func _ready() -> void:
	PacketHandler.lobby = self
	PacketHandler.connect("hosting", find_node("stophost"), "set_visible")
	PacketHandler.connect("connection_established", self, "reset")
	if !Utils.internet:
		set_status("no internet", false)
		set_buttons(false)


func reset():
	set_status("", true)
	set_buttons(true)


func focus():
	get_parent().current_tab = get_parent().get_children().find(self)


func set_status(text: String, isok: bool) -> void:  # Simple way to show status.
	if isok:
		status_ok.set_text(text)
		status_fail.set_text("")
	else:
		status_ok.set_text("")
		status_fail.set_text(text)
	status_ok.visible = len(status_ok.text) > 0
	status_fail.visible = len(status_fail.text) > 0


func set_buttons(enabled := true) -> void:
	for c in buttons.get_children():
		c.disabled = !enabled
	address.editable = enabled


func _on_join_pressed() -> void:
	if validate_text():
		set_buttons(false)
		PacketHandler.join_game()
	else:
		set_status("Invalid address", false)


func _on_HostButton_pressed() -> void:
	if validate_text():
		set_buttons(false)
		$Center/VBox/GameConfig.open(self)
	else:
		set_status("Invalid address", false)


func validate_text(text := address.get_text()) -> String:
	var pos := address.caret_position
	text = clean_text(text)
	address.text = text
	address.caret_position = pos
	PacketHandler.game_code = text
	return text


func clean_text(text: String) -> String:
	text = text.strip_edges()
	return text.replace(" ", "_")


func _on_Address_text_entered(new_text: String) -> void:
	validate_text(new_text)


func _on_spectate_pressed():
	if validate_text():
		set_buttons(false)
		PacketHandler.spectate()
	else:
		set_status("Invalid address", false)


func _on_stophost_pressed() -> void:
	PacketHandler.return()
	reset()