helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82


; variables
(variable_assignment (identifier) @variable.other.member)
(variable_assignment (concatenation (identifier) @variable.other.member))
(unset_statement (identifier) @variable.other.member)
(export_statement (identifier) @variable.other.member)
(variable_expansion (identifier) @variable.other.member)
(python_function_definition (parameters (python_identifier) @variable.other.member))

(variable_assignment (override) @keyword.storage.modifier)
(overrides_statement (identifier) @keyword.storage.modifier)
(flag) @keyword.storage.modifier

[
  "="
  "?="
  "??="
  ":="
  "=+"
  "+="
  ".="
  "=."

] @operator

[ "(" ")" "{" "}" "[" "]" ] @punctuation.bracket
(variable_expansion [ "${" "}" ] @punctuation.special)

[
  "noexec"
  "INHERIT"
  "OVERRIDES"
  "$BB_ENV_PASSTHROUGH"
  "$BB_ENV_PASSTHROUGH_ADDITIONS"
] @variable.builtin

; functions

(python_function_definition (python_identifier) @function)
(anonymous_python_function (identifier) @function)
(function_definition (identifier) @function)
(export_functions_statement (identifier) @function)
(addtask_statement (identifier) @function)
(deltask_statement (identifier) @function)
(addhandler_statement (identifier) @function)
(function_definition (override) @keyword.storage.modifier)

[
  "addtask"
  "deltask"
  "addhandler"
  "unset"
  "EXPORT_FUNCTIONS"
  "python"
  "def"
] @keyword.function

[
  "append"
  "prepend"
  "remove"

  "before"
  "after"
] @keyword.operator

; imports

[
  "inherit"
  "include"
  "require"
  "export"
  "import"
] @keyword.control.import

(inherit_path) @namespace
(include_path) @namespace


(string) @string
(comment) @comment