helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

(sym_lit) @variable

[
  (accumulation_verb)
  "thereis"
  "always"
  "below"
  "into"
  "as"
] @keyword

"and" @keyword.operator

[
  "when"
  "if"
  "unless"
  "else"
] @keyword.control.conditional

[
  "for"
  "loop"
  "while"
  "until"
  "do"
  "repeat"
] @keyword.control.loop

[
  "in"
  "across"
  "being"
  "from"

  "finally"
  "initially"

  "with"
] @keyword.control

"return" @keyword.control.return

(include_reader_macro) @keyword.directive

(defun_keyword) @keyword.function

(defun_header
  function_name: (_) @function)

(defun_header
  lambda_list: (list_lit
    (sym_lit) @variable.parameter))

(defun_header
  lambda_list: (list_lit
    (list_lit
      . (sym_lit) @variable.parameter)
      . (_)))

"=" @operator

; quote
(format_specifier) @operator

(quoting_lit "'" @operator)
(syn_quoting_lit "`" @operator)
(unquoting_lit "," @operator)
(unquote_splicing_lit ",@" @operator)

(var_quoting_lit
  marker: "#'" @operator)

(list_lit
  . (sym_lit) @operator
  (#any-of? @operator "+" "*" "-" "=" "<" ">" "<=" ">=" "/="))

(package_lit
  package: (_) @namespace)
"cl" @namespace

(str_lit) @string

(num_lit) @constant.numeric
["#c" "#C"] @constant.numeric
[
  (array_dimension)
  "#0A"
  "#0a"
] @constant.numeric

(nil_lit) @constant.builtin
(char_lit) @constant.character

[(comment) (block_comment)] @comment
(dis_expr) @comment

["(" ")"] @punctuaton.bracket
[":" "::" "."] @punctuation.special