helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

[
  (jinja2_expression)
  (jinja2_statement)
  (jinja2_comment)
  (jinja2_shebang)
] @special

(include_statement
  directive: _ @keyword.directive
  path: _ @string.special.path)

(comment) @comment.line

(graph_section
  name: _? @label)

(task_section
  name: (_
    (task_name) @namespace))

(top_section
  brackets_open: _ @punctuation.bracket
  name: _? @label
  brackets_close: _ @punctuation.bracket)

(sub_section_1
  brackets_open: _ @punctuation.bracket
  name: _? @label
  brackets_close: _ @punctuation.bracket)

(sub_section_2
  brackets_open: _ @punctuation.bracket
  name: _? @label
  brackets_close: _ @punctuation.bracket)

(runtime_section
  brackets_open: _ @punctuation.bracket
  name: _? @label
  brackets_close: _ @punctuation.bracket)

(graph_setting
  key: (_) @constant.numeric.integer
  operator: (_)? @operator)

(quoted_graph_string
  quotes_open: _ @string
  quotes_close: _ @string)

(multiline_graph_string
  quotes_open: _ @string
  quotes_close: _ @string)

[
  (graph_logical)
  (graph_arrow)
  (graph_parenthesis)
] @operator

(intercycle_annotation
  (recurrence) @constant.numeric.integer)

(graph_task
  xtrigger: _? @operator
  suicide: _? @operator
  name: _ @namespace)

(task_parameter
  "<" @tag
  name: (_)? @special
  ","? @tag
  "="? @tag
  selection: (_)? @special
  ">" @tag)

(intercycle_annotation
  "[" @tag
  (recurrence)? @constant.numeric.integer
  "]" @tag)

(task_output
  ":" @tag
  (nametag) @variable.other)

(task_output
  "?"? @tag)

(setting
  key: (key) @variable
  operator: (_)? @operator
  value: [
    (unquoted_string) @string
    (quoted_string) @string
    (multiline_string) @string
    (boolean) @constant.builtin.boolean
    (integer) @constant.numeric.integer
  ]?)

(datetime) @constant.numeric.float