helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

(string_array "," @punctuation.delimiter)
(string_array ["[" "]"] @punctuation.bracket)

[
    "ARG"
    "AS LOCAL"
    "BUILD"
    "CACHE"
    "CMD"
    "COPY"
    "DO"
    "ENTRYPOINT"
    "ENV"
    "EXPOSE"
    "FROM DOCKERFILE"
    "FROM"
    "FUNCTION"
    "GIT CLONE"
    "HOST"
    "IMPORT"
    "LABEL"
    "LET"
    "PROJECT"
    "RUN"
    "SAVE ARTIFACT"
    "SAVE IMAGE"
    "SET"
    "USER"
    "VERSION"
    "VOLUME"
    "WORKDIR"
] @keyword

(for_command ["FOR" "IN" "END"] @keyword.control.repeat)

(if_command ["IF" "END"] @keyword.control.conditional)
(elif_block ["ELSE IF"] @keyword.control.conditional)
(else_block ["ELSE"] @keyword.control.conditional)

(import_command ["IMPORT" "AS"] @keyword.control.import)

(try_command ["TRY" "FINALLY" "END"] @keyword.control.exception)

(wait_command ["WAIT" "END"] @keyword.control)
(with_docker_command ["WITH DOCKER" "END"] @keyword.control)

[
    (comment)
    (line_continuation_comment)
] @comment

(line_continuation) @operator

[
    (target_ref)
    (target_artifact)
    (function_ref)
] @function

(target (identifier) @function)

[
    (double_quoted_string)
    (single_quoted_string)
] @string
(unquoted_string) @string.special
(escape_sequence) @constant.character.escape

(variable) @variable
(expansion ["$" "{" "}" "(" ")"] @punctuation.special)
(build_arg) @variable
(options (_) @variable.parameter)

"=" @operator