helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

; inherits: json

; https://www.w3.org/TR/json-ld/#syntax-tokens-and-keywords
((string (string_content) @keyword)
 (#any-of? @keyword
   "@base"
   "@container"
   "@context"
   "@direction"
   "@graph"
   "@id"
   "@import"
   "@included"
   "@index"
   "@json"
   "@language"
   "@list"
   "@nest"
   "@none"
   "@prefix"
   "@propagate"
   "@protected"
   "@reverse"
   "@set"
   "@type"
   "@value"
   "@version"
   "@vocab"))

((pair
  value: (string (string_content) @string.special.url))
 (#match? @string.special.url "^https?://"))

((array
  (string (string_content) @string.special.url))
  (#match? @string.special.url "^https?://"))

; https://www.w3.org/TR/json-ld/#dfn-base-direction
((pair
  key: (string (string_content) @keyword)
  value: (string (string_content) @type.enum.variant))
 (#eq? @keyword "@direction")
 (#any-of? @type.enum.variant "ltr" "rtl"))