helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

; -----------
; Definitions
; -----------

; Constants
(const_statement
  (assignment
    . (identifier) @local.definition.constant))

; Parameters
(parameter_list
  (identifier) @local.definition.variable.parameter)

(optional_parameter
  .
  (identifier) @local.definition.variable.parameter)

(slurp_parameter
  (identifier) @local.definition.variable.parameter)

(typed_parameter
  parameter: (identifier) @local.definition.variable.parameter
  (_))

; Single parameter arrow function
(function_expression
  .
  (identifier) @local.definition.variable.parameter)

; ----------
; References
; ----------

(identifier) @local.reference
 
; ------
; Scopes
; ------

[
  (for_statement)
  (while_statement)
  (try_statement)
  (catch_clause)
  (finally_clause)
  (let_statement)
  (quote_statement)
  (do_clause)
  (function_definition)
  (short_function_definition)
  (macro_definition)
] @local.scope