helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158

; This file specifies how matched syntax patterns should be highlighted

[
  "export"
  "import"
  "unexport"
] @keyword.control.import

"mod" @keyword.directive

[
  "alias"
  "set"
  "shell"
] @keyword

[
  "if"
  "else"
] @keyword.control.conditional

[
  "&&"
  "||"
] @operator

; Variables

(value
  (identifier) @variable)

(alias
  alias_name: (identifier) @variable)

(assignment
  name: (identifier) @variable)

(shell_variable_name) @variable

(unexport
  name: (identifier) @variable)

; Functions

(recipe
  name: (identifier) @function)

(recipe_dependency
  name: (identifier) @function.call)

(function_call
  name: (identifier) @function.builtin)

; Parameters

(recipe_parameter
  name: (identifier) @variable.parameter)

; Namespaces

(mod
  name: (identifier) @namespace)

(module_path
  name: (identifier) @namespace)

; Paths

(mod
  (path) @string.special.path)

(import
  (path) @string.special.path)

; Shebangs

(shebang_line) @keyword.directive
(shebang_line
  (shebang_shell) @string.special)


(shell_expanded_string
  [
    (expansion_short_start)
    (expansion_long_start)
    (expansion_long_middle)
    (expansion_long_end)
  ] @punctuation.special)

; Operators

[
  ":="
  "?"
  "=="
  "!="
  "=~"
  "!~"
  "@"
  "="
  "$"
  "*"
  "+"
  "&&"
  "@-"
  "-@"
  "-"
  "/"
  ":"
] @operator

; Punctuation

"," @punctuation.delimiter

[
  "{"
  "}"
  "["
  "]"
  "("
  ")"
  "{{"
  "}}"
] @punctuation.bracket

[ "`" "```" ] @punctuation.special

; Literals

; Booleans are not allowed anywhere except in settings
(setting
  (boolean) @constant.builtin.boolean)

[
  (string)
  (external_command)
] @string

[
  (escape_sequence)
  (escape_variable_end)
] @constant.character.escape

; Comments

(comment) @comment.line

; highlight known settings
(setting
  name: (_) @keyword.function)

; highlight known attributes
(attribute
  name: (identifier) @attribute)

; Numbers are part of the syntax tree, even if disallowed
(numeric_error) @error