helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

; Scopes

[
  (chunk)
  (function_declaration)
  (function_definition)
  (do_statement)
  (while_statement)
  (repeat_statement)
  (if_statement)
  (for_statement)
] @local.scope

; Definitions

(parameters
  (identifier) @local.definition.variable.parameter)

; `self` in a method is an implicit parameter.
(parameters
  (identifier) @local.definition.variable.builtin
  (#eq? @local.definition.variable.builtin "self"))

(for_numeric_clause
  name: (identifier) @local.definition.variable)

(for_generic_clause
  (variable_list
    (variable
      (identifier) @local.definition.variable)))

; `local x, y = ...`
(variable_declaration
  (assignment_statement
    (variable_list
      (variable
        (identifier) @local.definition.variable))))
(variable_declaration
  (variable_list
    (variable
      (identifier) @local.definition.variable)))

; References

(identifier) @local.reference

; Field/member names are not variable references.
(dot_index_expression
  field: (identifier) @_)
(method_index_expression
  method: (identifier) @_)
(field
  name: (identifier) @_)