helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164

; Includes
(identifier) @variable

"include" @keyword.control.import

(include_path) @string.special.path

; Functions

(function_item
  (identifier) @function
)
(function_item
  parameters: (parameters (parameter (assignment value: (_) @constant)))
)
(function_call name: (identifier) @function)
(function_call
  arguments: (arguments (assignment name: _ @variable.parameter))
)
; for the puroposes of distintion since modules are "coloured" impure functions, we will treat them as methods
(module_item (identifier) @function.method)
(module_item
  parameters: (parameters (parameter (assignment value: (_) @constant)))
)
(module_call name: (identifier) @function.method)
(module_call
  arguments: (arguments (assignment name: _ @variable.parameter))
)

; assertion statements/expression arguments behave similar to function calls
(assert_expression
  arguments: (arguments (assignment name: _ @variable.parameter))
)
(assert_statement
  arguments: (arguments (assignment name: _ @variable.parameter))
)

(echo_expression
  arguments: (arguments (assignment name: _ @variable.parameter))
)
(echo_expression "echo" @function.builtin)

; Variables
(parameter
  [_ @variable.parameter (assignment name: _ @variable.parameter)]
)
(special_variable) @variable.builtin
(undef) @constant.builtin

; Types/Properties/
(dot_index_expression index: (_) @variable.other.member)

; Keywords
[
  "module"
  "function"
  "let"
  "assign"
  "use"
  "each"
  (assert_statement "assert")
  (assert_expression "assert")
] @keyword

; Operators
[
  "||"
  "&&"
  "=="
  "!="
  "<"
  ">"
  "<="
  ">="
  "+"
  "-"
  "*"
  "/"
  "%"
  "^"
  "!"
  ":"
  "="
] @operator

; Builtin modules
(module_call
  name: (identifier) @function.builtin
  (#any-of? @function.builtin
    "circle"
    "color"
    "cube"
    "cylinder"
    "difference"
    "hull"
    "intersection"
    "linear_extrude"
    "minkowski"
    "mirror"
    "multmatrix"
    "offset"
    "polygon"
    "polyhedron"
    "projection"
    "resize"
    "rotate"
    "rotate_extrude"
    "scale"
    "sphere"
    "square"
    "surface"
    "text"
    "translate"
    "union"
    "echo"
  )
)
(
  (identifier) @identifier
  (#eq? @identifier "PI")
) @constant.builtin

; Conditionals
[
  "if"
  "else"
] @keyword.control.conditional
(ternary_expression
  ["?" ":"] @keyword.control.conditional
)

; Repeats
[
  "for"
  "intersection_for"
] @keyword.control.repeat

; Literals
(integer) @constant.numeric.integer
(float) @constant.numeric.float
(string) @string
(escape_sequence) @constant.character.escape
(boolean) @constant.builtin.boolean

; Misc
(modifier
  [
    "*"
    "!"
    "#"
    "%"
  ] @keyword.storage.modifier
)
["{" "}"] @punctuation.bracket
["(" ")"] @punctuation.bracket
["[" "]"] @punctuation.bracket
[
  ";"
  ","
  "."
] @punctuation.delimiter

; Comments
[(line_comment) (block_comment)] @comment