helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

; Scopes

[
  (function_item)
  (struct_item)
  (enum_item)
  (union_item)
  (type_item)
  (trait_item)
  (impl_item)
  (closure_expression)
  (block)
] @local.scope

; Definitions

(function_item
  (parameters
    (parameter
      pattern: (identifier) @local.definition.variable.parameter)))

(closure_parameters (identifier) @local.definition.variable.parameter)

; Mutable variables

(let_declaration
  (mutable_specifier)
  pattern: (identifier) @local.definition.variable.mutable)
(mut_pattern
  (mutable_specifier)
  (identifier) @local.definition.variable.mutable)

(parameter
  (mutable_specifier)
  pattern: (identifier) @local.definition.variable.parameter.mutable)

(self_parameter
  (mutable_specifier)
  (self) @local.definition.variable.builtin.mutable)

; References
(self) @local.reference
(identifier) @local.reference

; lifetimes / labels
(lifetime (identifier) @label)
(label (identifier) @label)

; == scoped function calls and function defs ==
; avoid coloring functions as variables
; taken from highlights.scm
(call_expression
  function: (scoped_identifier
    name: (identifier) @function))
(generic_function
  function: (scoped_identifier
    name: (identifier) @function))

(function_item
  name: (identifier) @function)
(function_signature_item
  name: (identifier) @function)

; == other ==
(enum_variant (identifier) @type.enum.variant)