helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100

[
  (protocol_body)
  (class_body)
  (enum_class_body)
  (function_declaration)
  (init_declaration)
  (deinit_declaration)
  (computed_property)
  (subscript_declaration)
  (computed_getter)
  (computed_setter)
  (for_statement)
  (while_statement)
  (repeat_while_statement)
  (do_statement)
  (if_statement)
  (switch_statement)
  (guard_statement)
  (type_parameters)
  (tuple_type)
  (array_type)
  (dictionary_type)
  (call_expression)
  (tuple_expression)
  (array_literal)
  (dictionary_literal)
  (lambda_literal)
  (willset_didset_block)
  (willset_clause)
  (didset_clause)
  (value_arguments)
] @indent

[
  "}"
  "]"
  ")"
  ">"
] @outdent

(assignment
  .
  (_) @expr-start
  (_) @indent
  (#not-same-line? @indent @expr-start)
  (#set! "scope" "all")
)

(control_transfer_statement
  .
  (_) @expr-start
  (_) @indent
  (#not-same-line? @indent @expr-start)
  (#set! "scope" "all")
)

(if_statement
  (if_statement) @outdent
)

(switch_entry
  .
  _ @indent
  (#set! "scope" "tail")
)

(init_declaration
  (parameter) @indent
)

(modifiers
  (attribute) @indent
)

(type_parameters
  ">" @outdent
)

(tuple_expression
  ")" @outdent
)

(tuple_type
  ")" @outdent
)

(modifiers
  (attribute
    ")" @outdent
  )
)

(ERROR
  [
    "<"
    "{"
    "("
    "["
  ]
) @indent