helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129


(type_identifier) @type
((type_identifier) @type.builtin (#any-of? @type.builtin "int" "bool" "cell" "slice" "builder" "continuation" "tuple" "coins" "address" "void" "self"))

(identifier) @variable
((identifier) @constant
  (#match? @constant "^[A-Z][A-Z\\d_]*$"))
((identifier) @variable.builtin
 (#eq? @variable.builtin "self"))

(comment) @comment

[
  "(" ")"
  "{" "}"
] @punctuation.bracket

[
  ; "::"
  "."
  ";"
  ","
  ":"
] @punctuation.delimiter

[
  "do"
  "if"
  "as"
  "fun"
  "asm"
  "get"
  "try"
  "var"
  "val"
  "else"
  "true"
  "tolk"
  "const"
  "false"
  "throw"
  "redef"
  "while"
  "catch"
  "return"
  "assert"
  "import"
  "global"
  "repeat"
  "mutate"
  "struct"
  "type"
  "match"
  "lazy"
  (null_literal)
  (builtin_specifier)
] @keyword

[
  "="
  "+="
  "-="
  "*="
  "/="
  "%="
  "<<="
  ">>="
  "&="
  "|="
  "^="

  "=="
  "<"
  ">"
  "<="
  ">="
  "!="
  "<=>"
  "<<"
  ">>"
  "~>>"
  "^>>"
  "-"
  "+"
  "|"
  "^"
  "*"
  "/"
  "%"
  "~/"
  "^/"
  "&"
  "~"
  "."
  "!"
  "&&"
  "||"

  "->"
  "=>"
] @operator

(string_literal) @string
(number_literal) @constant.numeric
(boolean_literal) @constant.builtin.boolean

(annotation) @attribute

(function_declaration
  name: (identifier) @function)
(method_declaration
  name: (identifier) @function)
(get_method_declaration
  name: (identifier) @function)
(function_call
  callee: (identifier) @function)
(function_call
  callee: (dot_access (identifier) @type "." (identifier) @function))
(dot_access
  field: (identifier) @variable)


(struct_declaration
  "struct"
  name: (identifier) @type)
(struct_field_declaration
  name: (identifier) @variable.other.member)
(instance_argument
  name: (identifier) @variable.other.member)