helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

((program
  .
  (comment)*
  .
  (comment) @keyword.import)
  (#match? @keyword.import "^;+ *inherits *:"))

((parameters
  (identifier) @constant.numeric)
  (#match? @constant.numeric "^[-+]?[0-9]+(.[0-9]+)?$"))

"_" @constant

":" @punctuation.delimiter

[
  "["
  "]"
  "("
  ")"
] @punctuation.bracket

"." @operator

(quantifier) @operator

(comment) @comment

(negated_field
  "!" @operator
  (identifier) @variable.other.member)

(field_definition
  name: (identifier) @variable.other.member)

(named_node
  name: (identifier) @tag)

((predicate
   "#" @function.builtin
   name: (identifier) @function.builtin @_name
   type: (predicate_type) @function.builtin)
 (#any-of? @_name "eq" "not-eq" "match" "not-match" "any-of" "not-any-of" "is" "is-not" "not-same-line" "not-kind-eq" "set" "select-adjacent" "strip"))
(predicate name: (identifier) @error)

(capture) @label

(escape_sequence) @constant.character.escape

(string) @string