helix - Unnamed repository; edit this file 'description' to name the repository.


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

; Classes

(enum_statement
  (enum_body) @class.inside) @class.around

(model_statement
  (model_expression) @class.inside) @class.around

(union_statement
  (union_body) @class.inside) @class.around

; Interfaces

(interface_statement
  (interface_body
    (interface_member) @function.around) @class.inside) @class.around

; Comments

[
  (single_line_comment)
  (multi_line_comment)
] @comment.inside

[
  (single_line_comment)
  (multi_line_comment)
]+ @comment.around

; Functions

[
  (decorator)
  (decorator_declaration_statement)
  (function_declaration_statement)
  (operation_statement)
] @function.around

(function_parameter_list
  (function_parameter)? @parameter.inside)* @function.inside

(decorator_arguments
  (expression_list
    (_) @parameter.inside)*) @function.inside

(operation_arguments
  (model_property)? @parameter.inside)* @function.inside

(template_parameters
  (template_parameter_list
    (template_parameter) @parameter.inside)) @function.inside